7.4. Built-in Functions

Rexx provides a set of built-in functions, including character manipulation, conversion, and information functions. The following are general notes on the built-in functions:

The parentheses in a function are always needed, even if no arguments are required. The first parenthesis must follow the name of the function with no whitespace in between.
The built-in functions internally work with NUMERIC DIGITS 9 for 32-bit systems or NUMERIC DIGITS 18 for 64-bit systems, and NUMERIC FUZZ 0 and are unaffected by changes to the NUMERIC settings, except where stated. Any argument named as a number is rounded, if necessary, according to the current setting of NUMERIC DIGITS (as though the number had been added to 0) and checked for validity before use. This occurs in the following functions: ABS, FORMAT, MAX, MIN, SIGN, and TRUNC, and for certain options of DATATYPE.
Any argument named as a string can be a null string.
If an argument specifies a length, it must be a positive whole number or zero. If it specifies a start character or word in a string, it must be a positive whole number, unless otherwise stated.
If the last argument is optional, you can always include a comma to indicate that you have omitted it. For example, DATATYPE(1,), like DATATYPE(1), would return NUM. You can include any number of trailing commas; they are ignored. If there are actual parameters, the default values apply.
If you specify a pad character, it must be exactly one character long. A pad character extends a string, usually on the right. For an example, see the LEFT built-in function LEFT (Section 7.4.37, “LEFT”).
If a function has an option that you can select by specifying the first character of a string, that character can be in uppercase or lowercase.
Many of the built-in functions invoke methods of the String (Section 5.1.3, “The String Class” class. For the functions ABBREV, ABS, BITAND, BITOR, BITXOR, B2X, CENTER, CENTRE, CHANGESTR, COMPARE, COPIES, COUNTSTR, C2D, C2X, DATATYPE, DELSTR, DELWORD, D2C, D2X, FORMAT, LEFT, LENGTH, LOWER, MAX, MIN, REVERSE, RIGHT, SIGN, SPACE, STRIP, SUBSTR, SUBWORD, TRANSLATE, TRUNC, UPPER, VERIFY, WORD, WORDINDEX, WORDLENGTH, WORDS, X2B, X2C, and X2D, the first argument to the built-in function is used as the receiver object for the message sent, and the remaining arguments are used in the same order as the message arguments. For example, SUBSTR("abcde",3,2) is equivalent to "abcde"~SUBSTR(3,2).
For the functions INSERT, LASTPOS, OVERLAY, POS, and WORDPOS, the second argument to the built-in functions is used as the receiver object for the message sent, and the other arguments are used in the same order as the message arguments. For example, POS("a","Haystack",3) is equivalent to "Haystack"~POS("a",3).
The language processor evaluates all built-in function arguments to produce character strings.

7.4.1. ABBREV (Abbreviation)


>>-ABBREV(information,info--+---------+--)---------------------><
                            +-,length-+

Returns 1 if info is equal to the leading characters of information and the length of info is not less than length. It returns 0 if either of these conditions is not met.

If you specify length, it must be a positive whole number or zero. The default for length is the number of characters in info.

Here are some examples:

Example 7.4. Builtin function ABBREV examples

ABBREV("Print","Pri")      ->    1
ABBREV("PRINT","Pri")      ->    0
ABBREV("PRINT","PRI",4)    ->    0
ABBREV("PRINT","PRY")      ->    0
ABBREV("PRINT","")         ->    1
ABBREV("PRINT","",1)       ->    0

Note

A null string always matches if a length of 0, or the default, is used. This allows a default keyword to be selected automatically if desired; for example:

Example 7.5. Builtin function ABBREV example

say "Enter option:";   pull option .
select  /* keyword1 is to be the default */
  when abbrev("keyword1",option) then ...
  when abbrev("keyword2",option) then ...
  ...
  otherwise nop;
end;