/*кФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФП*/
/*Г      Copyright (c) 1993 by Command Technology Corporation       Г*/
/*УФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФД*/
/*Г                                                                 Г*/
/*Г   SPF/PC macro: EDITFILE.SPF                                    Г*/
/*Г                                                                 Г*/
/*УФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФД*/
/*Г                                                                 Г*/
/*Г   Usage: EDITFILE is best used when assigned to a key, like     Г*/
/*Г          Ctrl-E.  It allows you to be inside a source module    Г*/
/*Г          that makes reference to a copy book or a C include     Г*/
/*Г          file and, by positioning the cursor on top of the      Г*/
/*Г          name of the file and hitting the assigned key,         Г*/
/*Г          edit the file with a single keystroke.                 Г*/
/*Г                                                                 Г*/
/*Г          Unless a pathname is specified in the text, the        Г*/
/*Г          current directory is assumed.                          Г*/
/*Г                                                                 Г*/
/*Г   Notes: Due to a limitation in Version 3.0, when a macro is    Г*/
/*Г          active, you cannot perform SPLIT, FSPLIT or SWAP.      Г*/
/*Г          The EDITFILE macro technically does not terminate      Г*/
/*Г          until you exit out of the file that you have           Г*/
/*Г          selected.  Therefore, if you select a file to edit     Г*/
/*Г          with EDITFILE, you will not be allowed to perform      Г*/
/*Г          a SPLIT, SWAP, or FSPLIT until you exit out of that    Г*/
/*Г          edit session with an END or CANCEL command.            Г*/
/*Г                                                                 Г*/
/*Г          EDITFILE maybe executed repetatively inside each       Г*/
/*Г          other, so that you may select "file2" from within      Г*/
/*Г          "file1", and then select "file3" from within that      Г*/
/*Г          edit session.  The previous still remain open, and     Г*/
/*Г          will be display in their present state as you exit     Г*/
/*Г          out of the newly selected edit sessions.               Г*/
/*Г                                                                 Г*/
/*РФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФй*/

'ISREDIT MACRO'

/*------------------------------------------------------------*/
/* get cursor position and line data.                         */
/*------------------------------------------------------------*/
'isredit (line, column) = cursor'
'isredit (text)         = line .zcsr'
'isredit (lrecl)        = lrecl'
'isredit (cur_file)     = member'

/*------------------------------------------------------------*/
/* if cursor is not on a data line, then exit with a message. */
/*------------------------------------------------------------*/
if (column = 0) | (column > lrecl) then do
   ZEDSMSG = "PUT CURSOR ON A DATA LINE"
   ZEDLMSG = "THE NEXT OCCURRENCE OF THE GIVEN WORD WILL BE FOUND."
   'ISPEXEC SETMSG MSG(ISRZ001)'
   exit
end


/*------------------------------------------------------------*/
/* get first previous text position.                          */
/*------------------------------------------------------------*/
TableYes = '_\-:.*?' || xrange('0','9') || xrange('A','Z') || xrange('a','z');
TableNo  = translate(xrange(),,TableYes,' ')
wordmask = translate(text,,TableNo, ' ');
wordmask = translate(wordmask,,TableYes,'*');


/*------------------------------------------------------------*/
/* get the wordindex for the cursor position.                 */
/*------------------------------------------------------------*/
n  = 1;
Wi = 0
Wn = 0
do FOREVER;
   i = wordindex(wordmask,n);
   if (i = 0)       then leave;
   if (i <= column) then do
      Wi = i;
      Wn = n;
      end;
   else
      leave;
   n = n+1;
end;


/*------------------------------------------------------------*/
/* if no word found, exit with a message.                     */
/*------------------------------------------------------------*/
if (Wi = 0) then do
   ZEDSMSG = "PUT CURSOR ON FILE"
   ZEDLMSG = "THE GIVEN FILE WILL BE EDITED."
   'ISPEXEC SETMSG MSG(ISRZ001)'
   exit
end

/*------------------------------------------------------------*/
/* get word text.                                             */
/*------------------------------------------------------------*/
Wm = word(wordmask,Wn);
WFile = substr(text,Wi,length(Wm));

/*------------------------------------------------------------*/
/* check to see if we need to add a default extension         */
/*------------------------------------------------------------*/
if (pos('.',WFile)==0) then do
   ExtPos = pos('.', cur_file)
   if (ExtPos>0) then do
      WFile = WFile || substr(cur_file, ExtPos)
   end
end

/*------------------------------------------------------------*/
/* edit the file                                              */
/*------------------------------------------------------------*/
('ISREDIT EDIT ' || WFile )

